!!! Prutový model struktury A pro porovnání s analytickým výpočtem !!!

FINISH
/CLEAR

*ABBR,INPUT,'/INPUT,strukturaA_beam,txt'

*DO,step,40,90,5	! cyklus pro automaticky vypocet

*AFUN,RAD            
 PI=4*ATAN(1)       ! vypocet hodnoty PI
*AFUN,DEG             

!!!!!!!!!!!!!!!!!!!
!!! PREPROCESOR !!!
!!!!!!!!!!!!!!!!!!!

/PREP7


!!! Definice elementu !!!
ET,1,BEAM189

!!! Vstupni parametry !!!
alfa=step				! hodnota uhlu alfa	[°]			
H=10					! hodnota delky H [mm]
LH=1.25					! pomer L/H [-]				
p=0.75					! hodnota porozity [-]
Emod=200000				! modul pruznosti v tahu zakladniho materialu [MPa]
nu=0.4					! Poissonuv pomer zakladniho materialu [-]
Fappl=-1				! zatezna sila [N]
ELSIZE=0.5				! velikost prvku [mm]


L=LH*H					! automaticke vypocty potrebnych parametru
W=2*(2*H-L*cos(alfa))
H1=2*L*sin(alfa)
fi=90-alfa
p=1-p
SELTOL,1e-6
N=1

!!! Urceni tloustky pro zadanou hodnotu porozity !!!
alfa=alfa*PI/180	!rad

*AFUN,RAD 

ODM111=-0.3125*LH**2*P*cos(alfa)
ODM11=0.25*LH**2*p*(cos(alfa))**2+ODM111

ODM121=0.25*LH**2*cos(alfa)-0.25*LH**2
ODM12=0.0625*LH**2*P*cos(3*alfa)+ODM121

ODM1=ODM11+ODM12

ODM21=0.5*LH*cos(alfa)-0.5*LH+0.25*cos(alfa)-0.25
ODM22=-0.5*LH*p*cos(alfa)+LH*p
ODM2=-0.5*LH*P*(cos(alfa))**2+ODM22+ODM21

ODM=1.4142135623731*sqrt(-(ODM1+ODM2)*(tan(0.5*alfa))**2)*cos(0.5*alfa)

cast1=LH*(sin(0.5*alfa))**2

cast2=(sin(0.5*alfa))**2

jmenovatel=(cos(alfa))**2+cos(alfa)-2

A=-(4*H*(cast1-ODM+cast2)*sin(alfa))/jmenovatel		! vysledne rozmery pricneho prurezu
B=A

*AFUN,DEG  
alfa=alfa*180/pi

!!! Definice materialu !!!
MP,EX,1,Emod
MP,PRXY,1,,nu

!!! Tvorba zakladni geometrie !!!
K,1,H-L*cos(alfa),0,0
K,2,H,L*sin(alfa),0
K,3,-H,L*sin(alfa),0
K,4,-H+L*cos(alfa),0,0
K,5,-H,-L*sin(alfa),0
K,6,H,-L*sin(alfa),0
K,7,2*H-L*cos(alfa),0,0
K,8,-2*H+L*cos(alfa),0,0

L,1,2	$	L,2,3	$	L,3,4	$	L,4,5	$	L,5,6	$	L,6,1	$	L,1,7	$	L,4,8

!!! Vytvoreni struktury !!!
LSEL,ALL
LGEN,N,ALL,,,2*(2*H-L*cos(alfa)),0,0,,0

LSEL,ALL	$	LSEL,U,LOC,Y,-L*sin(alfa)
LGEN,N,ALL,,,0,2*L*sin(alfa),0,,0

ALLSEL,ALL

!!! Spojeni bodu !!!
NUMMRG,KP,0.000001
NUMMRG,NODE,0.000001

!!! Tvorba site !!!
SECTYPE,1,BEAM,RECT,profil1
SECDATA,A,B

SECTYPE,2,BEAM,RECT,profil2
SECOFFSET,CENT,A
SECDATA,A/2,B

LSEL,ALL	$	LSEL,U,LOC,Y,-L*sin(alfa)	$	LSEL,U,LOC,Y,(2*N-1)*L*sin(alfa)
LATT,1,,1,,,,1
ESIZE,ELSIZE
LMESH,ALL
/ESHAPE,1 

LSEL,S,LOC,Y,-L*sin(alfa)	$	LSEL,A,LOC,Y,(2*N-1)*L*sin(alfa)
LATT,1,,1,,,,2
ESIZE,ELSIZE
LMESH,ALL
/ESHAPE,ALL 

!!! Okrajove podminky !!!
NSEL,S,LOC,Y,(2*N-1)*L*sin(alfa)		$	CP,1,UY,ALL		$	D,ALL,UZ,0		$	D,ALL,ROTX,0	$	D,ALL,ROTY,0	$	D,ALL,ROTZ,0		
NSEL,S,LOC,Y,-L*sin(alfa)				$	D,ALL,UY,0		$	D,ALL,UZ,0		$	D,ALL,ROTX,0	$	D,ALL,ROTY,0	$	D,ALL,ROTZ,0
NSEL,S,LOC,X,-2*H+L*cos(alfa)			$	D,ALL,UX,0		$	D,ALL,ROTX,0	$	D,ALL,ROTY,0	$	D,ALL,ROTZ,0
NSEL,S,LOC,X,(2*N-1)*(2*H-L*cos(alfa))	$	CP,2,UX,ALL		$	D,ALL,ROTX,0	$	D,ALL,ROTY,0	$	D,ALL,ROTZ,0

ALLSEL,ALL

!!! Zatizeni !!!
NSEL,S,LOC,Y,(2*N-1)*L*sin(alfa)	$	NSEL,R,LOC,X,0
F,ALL,FY,Fappl

ALLSEL,ALL


!!!!!!!!!!!!!!!!
!!! SOLUTION !!!
!!!!!!!!!!!!!!!!
	
/SOLU

	
SOLVE


!!!!!!!!!!!!!!!!!!!!!
!!! POSTPROCESSOR !!!
!!!!!!!!!!!!!!!!!!!!!

SELTOL,1e-6

!!! Zjisteni posuvu ve smeru x !!!
NSEL,S,LOC,X,-2*H+L*cos(alfa)	$	NSEL,R,LOC,Y,0
*GET,minnode1,NODE,0,NUM,MIN
*GET,UXdisp1,NODE,minnode1,U,X

NSEL,S,LOC,X,(2*N-1)*(2*H-L*cos(alfa))	$	NSEL,R,LOC,Y,0
*GET,minnode2,NODE,0,NUM,MIN
*GET,UXdisp2,NODE,minnode2,U,X

!!! Zjisteni posuvu ve smeru y !!!
NSEL,S,LOC,X,0	$	NSEL,R,LOC,Y,(2*N-1)*L*sin(alfa)	
*GET,minnode3,NODE,0,NUM,MIN
*GET,UYdisp1,NODE,minnode3,U,Y

NSEL,S,LOC,X,0	$	NSEL,R,LOC,Y,-L*sin(alfa)
*GET,minnode4,NODE,0,NUM,MIN
*GET,UYdisp2,NODE,minnode4,U,Y

!!! Vypocet Poissonova pomeru !!!
dX=-UXdisp1+UXdisp2
dY=UYdisp1

X0=(2*H-L*cos(alfa))*2*N
Y0=2*N*L*sin(alfa)

epsX=dX/X0
epsY=dY/Y0

nuCALC=-epsX/epsY				! hodnota vysledneho Poissonova pomeru [-]

!!! Urceni plochy bunek !!!
S=N*2*(2*H-L*cos(alfa))*B

!!! Vypocet E !!!
sigma=Fappl/S
Ecalc=abs(sigma/epsY)/Emod		! hodnota vysledneho pomerneho modulu pruznosti v tahu [-]

!!!			  !!!
!!! Export dat!!!
!!!			  !!!

*CFOPEN,alfa,txt,,APPEND
*VWRITE,alfa
(1F12.6)
*CFCLOS

*CFOPEN,Ecalc,txt,,APPEND
*VWRITE,Ecalc
(1F14.12)
*CFCLOS

*CFOPEN,nuCALC,txt,,APPEND
*VWRITE,nuCALC
(1F12.6)
*CFCLOS

/CLEAR

*ENDDO

*ABBR,INPUT,'/INPUT,strukturaA_beam,txt' 